Si (Faux)
   ` MATH_EcartType [Antoine Galmiche 07/2002]
   ` ---------------------------------------------
   ` Rappels mathématiques :
   ` L'écart type d'une série mesure la dispersion des valeurs autour de la moyenne
   ` ---------------------------------------------
   ` MATH_EcartType (->TableauValeurs) -> Numérique
   ` TableauValeurs (Pointeur) Pointeur tableau réel de la série
   ` Résultat (Numérique) EcartType
   ` ---------------------------------------------
   ` MATHERROR
   ` 0 -> Pas d'erreur
   ` -1 -> Tableau de taille nulle
   ` ---------------------------------------------
   ` EXEMPLES
   ` L'écart type (arrondi) de {1,2,3,4} est 1,118
   ` L'écart type (arrondi) de {8,7,6,5} est 1,118
   ` L'écart type (arrondi) de {7,5,8,6} est 1,118
   ` L'écart type (arrondi) de {77,55,88,66} est 12,23
   `  
Fin de si 

C_ENTIER LONG(MATHERROR)
C_POINTEUR($1)  ` pointeur tableau de valeurs réelles
C_REEL($0)
$0:=0

  ` Traitement des erreurs
Au cas ou 
 : (Taille tableau($1->)=0)
 MATHERROR:=-1
Sinon 
 MATHERROR:=0
Fin de cas 

  ` Algorithme
Si (MATHERROR=0)
 C_REEL($x2;$x)
 C_ENTIER LONG($i;$k)
 
 $k:=Taille tableau($1->)
 $x2:=0
 $x:=0
 
 Boucle ($i;1;$k)
  $x2:=$x2+($1->{$i}^2)  ` Sommex2
  $x:=$x+$1->{$i}  ` Sommex
 Fin de boucle 
 
 $0:=$k*$x2  ` nSommex2
 $0:=$0-($x^2)  ` nSommex2 - (Sommex)2
 $0:=$0/($k^2)  ` (nSommex2 - (Sommex)2) / n2
 $0:=Racine carree($0)  ` Ã( (nSommex2 - (Sommex)2) / n2 )
Fin de si