Si (Faux)
   ` MATH_Gauss [Teddy LINET 08/2002]
   ` ---------------------------------------------
   ` Méthode toute bête renvoyant la densité de probabilité en X
   ` Selon une distribution normale de moyenne mu et d'écart-type s
   ` ---------------------------------------------
   ` Rappels mathématiques :
   ` La distribution normale, ou de Laplace-Gauss, appelée aussi gaussienne est une 
   ` distribution continue de la forme :
   ` 
   `                              (x-mu)^2
   `            1        -1/2------------
   ` Y = --------e          s^2
   `       s sqr(2pi)
   ` ---------------------------------------------
   ` Synthaxe : MATH_Gauss(VariableX;Moyenne;EType)
   ` Les 3 paramètres sont des reels
   ` ---------------------------------------------
   ` MATHERROR
   ` 0 -> Pas d'erreur
   ` -1->Ecart-type nul
   ` +1 -> Ecart-type négatif (mis à positif)
   ` ---------------------------------------------
   ` 
Fin de si 

C_ENTIER LONG(MATHERROR)
MATHERROR:=0  ` Tout marche jusqu'à preuve du contraire

C_REEL($1;$2;$3;$0;$VariableY_F;$VariableX_F;$vMoyenne_F;$vEType_F;$vVarTravail_F)
$VariableX_F:=$1
Si (Nombre de parametres<2)  ` pas de moyenne
 $vMoyenne_F:=0  ` On centre
Sinon 
 $vMoyenne_F:=$2
Fin de si 
Si (Nombre de parametres<3)  ` Pas d'ecart-type
 $vEType_F:=1  ` On reduit
Sinon 
 $vEType_F:=$3
Fin de si 
Au cas ou 
 : ($vEType_F=0)  ` Pas de division par 0
 MATHERROR:=-1
 : ($vEType_F<0)
 MATHERROR:=1
 $vEType_F:=Abs($vEType_F)  ` Valeur absolue
Fin de cas 

$VariableY_F:=0

Si (MATHERROR>=0)
 $VariableY_F:=$VariableX_F-$vMoyenne_F
 $VariableY_F:=$VariableY_F*$VariableY_F
 $VariableY_F:=$VariableY_F/($vEType_F*$vEType_F)
 $VariableY_F:=-$VariableY_F/2
 $VariableY_F:=Exp($VariableY_F)
 $vVarTravail_F:=2*Pi 
 $vVarTravail_F:=Racine carree($vVarTravail_F)
 $vVarTravail_F:=$vEType_F*$vVarTravail_F
 $vVarTravail_F:=1/$vVarTravail_F
 $VariableY_F:=$vVarTravail_F*$VariableY_F
Fin de si 

$0:=$VariableY_F